Windows: create nsis package using cake

CMakeLists.txt

@@ -139,7 +139,7 @@ elseif(WIN32)
     set(CPACK_NSIS_HELP_LINK "https://github.com/Daenyth/Cockatrice")
     set(CPACK_NSIS_URL_INFO_ABOUT "https://github.com/Daenyth/Cockatrice")
     set(CPACK_NSIS_CONTACT "Daenyth+github@gmail.com")
-    set(CPACK_NSIS_MODIFY_PATH ON)
+    set(CPACK_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/nsis")
 endif()
 
 include(CPack)

nsis/NSIS.template.in

+!include "MUI2.nsh"
+!include "FileFunc.nsh"
+
+!define /date TIMESTAMP "%Y%m%d"
+!searchparse /file ../../../cockatrice/version_string.cpp '= "' VERSION '";'
+
+Name "Cockatrice"
+OutFile "cockatrice_win32_${TIMESTAMP}_git-${VERSION}.exe"
+SetCompressor /SOLID lzma
+InstallDir "$PROGRAMFILES\Cockatrice"
+
+!define MUI_ABORTWARNING
+!define MUI_WELCOMEFINISHPAGE_BITMAP "..\..\..\..\nsis\leftimage.bmp"
+!define MUI_UNWELCOMEFINISHPAGE_BITMAP "..\..\..\..\nsis\leftimage.bmp"
+!define MUI_HEADERIMAGE
+!define MUI_HEADERIMAGE_BITMAP "..\..\..\..\nsis\headerimage.bmp"
+!define MUI_HEADERIMAGE_UNBITMAP "..\..\..\..\nsis\headerimage.bmp"
+!define MUI_WELCOMEPAGE_TEXT "This wizard will guide you through the installation of Cockatrice.$\r$\n$\r$\nClick Next to continue."
+!define MUI_FINISHPAGE_RUN "$INSTDIR/oracle.exe"
+!define MUI_FINISHPAGE_RUN_TEXT "Run card database downloader now"
+!define MUI_FINISHPAGE_RUN_PARAMETERS "-dlsets"
+
+!insertmacro MUI_PAGE_WELCOME
+!insertmacro MUI_PAGE_LICENSE "..\..\..\..\COPYING"
+!insertmacro MUI_PAGE_COMPONENTS
+!insertmacro MUI_PAGE_DIRECTORY
+!insertmacro MUI_PAGE_INSTFILES
+!insertmacro MUI_PAGE_FINISH
+
+!insertmacro MUI_UNPAGE_CONFIRM
+!insertmacro MUI_UNPAGE_INSTFILES
+!insertmacro MUI_UNPAGE_FINISH
+
+!insertmacro MUI_LANGUAGE "English"
+
+Section "Application" SecApplication
+	SetShellVarContext all
+	SetOutPath "$INSTDIR"
+
+	File /r ..\..\..\Release\*.*
+
+	WriteUninstaller "$INSTDIR\uninstall.exe"
+	${GetSize} "$INSTDIR" "/S=0K" $0 $1 $2
+	IntFmt $0 "0x%08X" $0
+	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Cockatrice" "DisplayName" "Cockatrice"
+	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Cockatrice" "UninstallString" "$\"$INSTDIR\uninstall.exe$\""
+	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Cockatrice" "QuietUninstallString" "$\"$INSTDIR\uninstall.exe$\" /S"
+	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Cockatrice" "InstallLocation" "$INSTDIR"
+	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Cockatrice" "DisplayIcon" "$INSTDIR\cockatrice.exe"
+	WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Cockatrice" "EstimatedSize" "$0"
+SectionEnd
+
+Section "Update configuration" SecUpdateConfig
+	WriteRegStr HKCU "Software\Cockatrice\Cockatrice\paths" "carddatabase" "$APPDATA\Cockatrice\cards.xml"
+	WriteRegStr HKCU "Software\Cockatrice\Cockatrice\paths" "decks" "$APPDATA\Cockatrice\decks"
+	WriteRegStr HKCU "Software\Cockatrice\Cockatrice\paths" "pics" "$APPDATA\Cockatrice\pics"
+	WriteRegStr HKCU "Software\Cockatrice\Cockatrice\sound" "path" "$APPDATA\Cockatrice\sounds"
+SectionEnd
+
+Section "Start menu item" SecStartMenu
+	createDirectory "$SMPROGRAMS\Cockatrice"
+	createShortCut "$SMPROGRAMS\Cockatrice\Cockatrice.lnk" "$INSTDIR\cockatrice.exe" '--debug-output'
+	createShortCut "$SMPROGRAMS\Cockatrice\Oracle.lnk" "$INSTDIR\oracle.exe"
+	createShortCut "$SMPROGRAMS\Cockatrice\Usermanual.lnk" "$INSTDIR\Usermanual.pdf"
+SectionEnd
+
+Section Uninstall
+SetShellVarContext all
+	RMDir /r "$INSTDIR\zonebg"
+	RMDir /r "$INSTDIR\plugins"
+	RMDir /r "$INSTDIR\sounds"
+	RMDir /r "$INSTDIR\translations"
+	Delete "$INSTDIR\uninstall.exe"
+	Delete "$INSTDIR\cockatrice.exe"
+	Delete "$INSTDIR\oracle.exe"
+	Delete "$INSTDIR\Usermanual.pdf"
+	Delete "$INSTDIR\libprotobuf.lib"
+	Delete "$INSTDIR\Qt*.dll"
+	RMDir "$INSTDIR"
+
+	RMDir "$SMPROGRAMS\Cockatrice"
+
+	DeleteRegKey HKCU "Software\Cockatrice"
+	DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Cockatrice"
+SectionEnd
+
+LangString DESC_SecApplication ${LANG_ENGLISH} "Cockatrice program files"
+LangString DESC_SecUpdateConfig ${LANG_ENGLISH} "Update the paths in the application settings according to the installation paths."
+LangString DESC_SecStartMenu ${LANG_ENGLISH} "Create start menu items for Cockatrice and Oracle."
+!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
+	!insertmacro MUI_DESCRIPTION_TEXT ${SecApplication} $(DESC_SecApplication)
+	!insertmacro MUI_DESCRIPTION_TEXT ${SecUpdateConfig} $(DESC_SecUpdateConfig)
+	!insertmacro MUI_DESCRIPTION_TEXT ${SecStartMenu} $(DESC_SecStartMenu)
+!insertmacro MUI_FUNCTION_DESCRIPTION_END
+